This is my solution in Nim:

import strutils, strformat

const digitStrings = ["one", "two", "three", "four", "five", "six", "seven", "eight", "nine"]

### Type definiton for a proc to extract a calibration function from a line
type CalibrationExtracter = proc (line:string): int

## extract a calibration value by finding the first and last numerical digit, and concatenating them
proc extractCalibration1(line:string): int =
  var first,last = -1
    
  for i, c in line:
    if c.isDigit:
      last = parseInt($c)
      if first == -1:
        first = last
        
  result = first * 10 + last

## extract a calibration value by finding the first and last numerical digit OR english lowercase word for a digit, and concatenating them
proc extractCalibration2(line:string): int =
  var first,last = -1
  
  for i, c in line:
    if c.isDigit:
      last = parseInt($c)
      if first == -1:
        first = last
    else: #not a digit parse number words
      for dsi, ds in digitStrings:
        if i == line.find(ds, i):
          last = dsi+1
          if first == -1:
            first = last
          break #break out of digit strings
        
  result = first * 10 + last

### general purpose extraction proc, accepts an extraction function for specific line handling
proc extract(fileName:string, extracter:CalibrationExtracter, verbose:bool): int =
  
  let lines = readFile(fileName).strip().splitLines();
  
  for lineIndex, line in lines:
    if line.len == 0:
      continue
    
    let value = extracter(line)
    result += value
    
    if verbose:
      echo &"Extracted {value} from line {lineIndex} {line}"

### public interface for puzzle part 1
proc part1*(input:string, verbose:bool = false): int =
  result = input.extract(extractCalibration1, verbose);

### public interface for puzzle part 2
proc part2*(input:string, verbose:bool = false): int =
  result = input.extract(extractCalibration2, verbose);